在ansys分析过程中，若要获得更精细的解答，一般需要通过细分网格的方法实现。但也许有时候网格划分不是那么方便，此时就需要在网格密度不变的前提下，获得更精确的解答——这就需要P方法了。
P方法的基本原理，是提高单元位移形函数的多项式次数，以达到收敛需要的精度。
适用性
P方法用于线弹性结构分析—实体和壳体。P单元由以下5种单元：
- 2-D Quadrilateral (Plane145)
- 2-D Triangle (Plane146)
- 3-D Brick (Solid 147)
- 3-D Tetrehedron (Solid 148)
- 3-D Shell (Solid 150)
ET,1,PLANE145,3,8
/PREP7 !进入前处理
/TITLE, EX 4.3, p-Method Analysis of Planar Plate with hole (Zeng P)
ANTYPE,STATIC !设定为静力结构分析
ET,1,PLANE145,,,3 !设置 1 号单元(p 型单元)
MP,EX,1,2e5 $MP,PRXY,1,0.25 !设置 1 号材料弹性常数
L=150 $H=80 $R1=5 $R2=10 $t=0.5 !设置几何参数
Pressure=100 !设置载荷参数
RECTNG,0,L,0,H !建立一个矩形面
WPOFFS,L/3,, !平移工作平面(x1=L/3)
PCIRC,R2,0,0,360 !建立一个圆面(R2)
WPOFFS,L/3,, !再平移工作平面(x2=x1+L/3)
PCIRC,R1,0,0,360 !建立一个圆面
R,1,t !设置厚度
ASBA,1,2 !将面 1 减面 2，则生成面 4
ASBA,4,3 !将面 4 减面 3
SMRTSIZ,4 !设置自动网格划分指数
AMESH,1 !对面进行单元划分
NSEL,S,LOC,X,0 !选取 x=0 节点
D,ALL,UX,0 !施加对称约束
!DSYM,SYMM,X !施加对称约束(与上一条命令的效果相同)
NSEL,S,LOC,Y,0 !选取 y=0 节点
DSYM,SYMM,Y !施加对称约束
NSEL,S,LOC,X,L !选取右边界节点
SF,ALL,PRES,-Pressure !对所选择节点施加载荷
ALLSEL !选取所有对象
FINISH !退出前处理
/SOLU !进入求解模块
P1=NODE(2*L/3,R1,0) !获取位置(2*L/3,R1,0)处的节点号，赋给参数 P1
P2=NODE(L/3,R2,0) !获取位置(L/3,R2,0)处的节点号，赋给参数 P2
PMOPTS !设置 p 方法中固定单元 p 阶次的误差，默认 5%
PCONV,0.5,S,X,P1 !针对 P1 节点，采用 p 方法，设置应力 SX 的误差在 0.1%以内
PCONV,0.5,S,X,P2 !针对 P2 节点，采用 p 方法，设置应力 SX 的误差在 0.1%以内
SOLVE !进行求解
/POST1 !进入后处理
SET,1 !调出结果的 1 号数据集
PLNSOL,S,X !图形显示 x 方向的应力计算结果
PLDISP,1 !图形显示受力后的模型结构
*GET,P1_SX,NODE,P1,S,X !获取节点 P1 处的应力 SX，赋给参数 P1_SX
*GET,P2_SX,NODE,P2,S,X !获取节点 P2 处的应力 SX，赋给参数 P2_SX
PLCONV !图形显示 p 方法的收敛曲线
PPLOT !图形显示实际所用单元 p 阶次
*STATUS !列显参数的内容
FINISH !结束
